#| Copyright 2025 Peter McGoron
 |
 | Licensed under the Apache License, Version 2.0 (the "License");
 |
 | you may not use this file except in compliance with the License.
 | You may obtain a copy of the License at
 |
 |     http://www.apache.org/licenses/LICENSE-2.0
 |
 | Unless required by applicable law or agreed to in writing, software
 | distributed under the License is distributed on an "AS IS" BASIS,
 | WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 | See the License for the specific language governing permissions and
 | limitations under the License.
 |#

;;; ;;;;;;;;;;;;
;;; API
;;; ;;;;;;;;;;;;

(define set-global-SAHP!
  (case-lambda
    ((SAHP type procedure)
     (set-global-SAHP! SAHP type '() procedure))
    ((SAHP type flag procedure)
     (%SAHP-set (SAHP-global-scope (extract-SAHP-descriptor SAHP))
                (list (list type flag procedure))))))

(define-syntax define-global-SAHP
  (syntax-rules ()
    ((_ (name (type flag arg1) . arg-rest) body ...)
     (set-global-SAHP! name
                       type
                       flag
                       (lambda (arg1 . arg-rest)
                         body ...)))
    ((_ (name (type arg1) . arg-rest) body ...)
     (set-global-SAHP! name
                       type
                       (lambda (arg1 . arg-rest)
                         body ...)))))

(define-syntax parameterize-SAHP
  (syntax-rules ()
    ((_ ((SAHP (type value) ...) ...) body ...)
     (parameterize-SAHP ((SAHP (type '() value) ...) ...) body ...))
    ((_ ((SAHP (type flag value) ...) ...) body ...)
     (let ((param (SAHP-dynamic-scope-parameter (extract-SAHP-descriptor
                                                 SAHP)))
           ...)
       (parameterize ((param (%SAHP-set (param)
                                        (list (list type flag value)
                                              ...)))
                      ...)
         body ...)))))

(define-syntax letrec-SAHP
  (syntax-rules ()
    ((_ ((SAHP (type value) ...) ...) body ...)
     (letrec-SAHP ((SAHP (type '() value) ...) ...) body ...))
    ((_ ((SAHP (type flag value) ...) ...) body ...)
     (let ((%SAHP (extract-SAHP-descriptor SAHP)) ...)
       (letrec ((SAHP (%SAHP/local-scope
                       %SAHP
                       (%SAHP-set (SAHP-local-scope %SAHP)
                                  (list (list type flag value)
                                        ...))))
                ...)
         body ...)))))